chauffage solaire douche piscine

MGU · Jun 18, 2025

Croisons les doigts, bizarre, le code erreur ne correspond pas à ce type de problème. Il y a combien de m ? Il y a une R de pullup sur l'arrivée TC ?
Les essais avec un MAX6675 donnaient une petite erreur de 2 ou 3 degrés, corrigés par ce potar.
Le MAX31855 est plus précis, doit y avoir une correction de t° interne.
On peut d'ailleurs sortir cette t°, je ne l'ai pas fait pour simplifier, mais si besoin, c'est juste une modif de code.
Faut modifier la présentation de l'affichage, pour éviter les mélanges.
MM

patrick63730 · Jun 18, 2025

il y as 3m50 environ pour la R de pullup sur l'arrivée TC c'est du pcb principal dont tu parle a la réception du signal sérigraphie D sur pcb? il y as une 4.7k qui était pour la DS, pour la T donnée par le TC j'ai essayé de régler le potar mais cela n'a eu aucun effet sur la T c'est pour cela que je posait la question , pour l'affichage j'ai le même sur la régulation thermique solaire et a part a la MST ou le message d'erreur apparait ça fonctionne bien je vais surveiller demain et il faut que j'ajoute un poussoir de validation sur mon boitier actuellement j'ai fait un montage volant pour les essais ,bonne soirée et merci encore
patrick

MGU · Jun 18, 2025

Normalement, on peut aller jusqu'à 15m sans soucis si pas trop de parasites.
Voir si les messages d'erreur sont utiles, si ils sont gênants, on peut les supprimer.
Ils ne doivent fonctionner qu'en cas de panne réelles
TC débranché => erreur TC : Le thermocouple est déconnecté.
Pas de message reçu pendant plus de 5s =>pas de trame reçue => problème sur le module ou pb de transmission
Et c'est tout
MM

MGU · Jun 19, 2025

Bonjour,
Je pense faire une modif plus radicale sur les codes des deux PCB, émetteur et récepteur.
- Faire la moyenne des mesures dans le module émetteur, il y aura moins de transmissions
-Réintroduire l'identifiant que j'avais supprimé pour simplifier mais qui permet simplement d'éliminer les trames polluées
Modifs à suivre, maintenant que la programmation fonctionne sans pb
MM

MGU · Jun 19, 2025

Mise à jour du jour:
Code pour le thermocouple.
La moyenne sur 4 mesures est faite dans ce code
Ajout d'un identifiant pour éliminer les éventuelles trames corrompues dans la liaison

Code:

;MESURE TMAX31855 RS232 19/06/25
;lecture thermocouple par MAX31855 MM 13/06/25
;La broche SO va prendre successivement la valeur de chaque bit du registre.
; scanné poids fort en tête
;moyenne sur 4 mesures
;transmission : temp, def, identifiant=123
#picaxe 08M2
#no_data
symbol CLK=C.1        ; pulse horloge
symbol CSB=C.2        ;demande lecture  _____/
symbol SO=pinC.3      ;bit de donnée serial out
symbol def=bit0
symbol cpt=b1
symbol temp=b2 
symbol varw=w13         ;var temporaire
symbol cumul=w12
symbol temptherm=w11    ;tempé thermocouple
setfreq M4                
symbol baud=T2400_4
;*****************************
#macro spin(varw)        ;macro SPIIN
    varw = 0
    for cpt = 1 to 16
      varw=varw * 2 + SO      ;décalage à gauche + SO (0 ou 1)    
      pulsout CLK,1           ;pulse horloge     
    next cpt    
#endmacro
;************************************
    pause 500    
    high CSB    ;première conversion
    Do   
        cumul=0
        for cpt = 1 to 4  
            pause 200     ;200 ms
            low CSB            ;lecture registre            
            spin(temptherm)    ;exécution macro 16 premiers bits (poid fort en tête    
            high CSB           ;nouvelle conversion    
            ;*****defaut **********************        
            def=temptherm//2        ;isol bit défaut        
            ;**** temp thermocouple ******************************          
            temptherm=temptherm/4        ;suppression des 2 derniers bits
            if temptherm>=$2000 then   ;test 1er bit des 14 bits pour valeur négative
              temptherm=0                    ;fixé à 0 si négatif    
            endif          
            temptherm=temptherm/4        ;suppression des décimales-> val entière
            temptherm=temptherm//256   ;valeur entière ; on garde les 8 derniers bits
            temp=temptherm     
            cumul=cumul + temp
        next
        temp=cumul/4    
        serout C.0, baud,(temp,def,123)        ;liaison RS232          
      loop

Code pour le PCB affichage:
Les trames non reconnues sont ignorées, on garde la valeur précédente
La position de la pompe de recyclage 'P" est en bout de ligne : A=Arrêt ;M=Marche
Les deux lignes du bas sont pour les erreurs et info de reset par un poussoir reset (encore nommé ""valid" dans ce programme)
Normalement, l'usage de ce poussoir est rare...

Code:

;chauffage solaire douche piscine 19/06/25
;T panneau par thermocouple et liaison RS232
;Identifiant =123
#picaxe 20M2
setfreq M16
symbol LCD=B.0
symbol Pbal=B.5
symbol circBal=pinB.1
symbol DSbalon=C.5
symbol pano=C.7
symbol Tpano =b1
symbol selec=pinC.6
symbol valid=pinC.0
symbol Tbalon =b2
symbol Cbalon =b3
symbol varb =b4
symbol memoTpano=b5
symbol delt =b6
symbol ident =b7
symbol cpt =b8
symbol affcirc=b9
symbol cumul =w13
symbol baud =N2400_16
symbol baudT =T2400_16
symbol def =bit0
dirsC=%0
dirsB=%00011111
pullup %1111111100000000
;****************************************
    pause 500
    serout LCD, baud,(254,1)
    serout LCD, baud,(254,131,"Tpa  Tba  Cba  P")
    serout LCD, baud,(254,192,"Tß") ;ß=alt+0223 => ° sur LCD
    do
        memoTpano=Tpano    
        serin [20000,erreur],C.7,baudT,Tpano,def,ident ;reception Tpano,def,ident timeout 5s
    ;    Tpano=120 : def=0 : ident=123        ;pour simu
        if def<>0 then erreur
        if ident<>123 then    ;si iden non reconnu, on garde l'ancienne valeur
            Tpano=memoTpano
        endif        
        readtemp DSbalon,Tbalon ;sur C.5
        readadc Pbal, Cbalon
        serout LCD, baud,(254,195,#Tpano," ",254,200,#Tbalon," ", 254,205,#Cbalon," ")
        pause 200
        gosub gescirc
    loop
    ;*********************************************
    gescirc:
    if Tbalon>=90 or Tbalon>=Tpano then
        circBal=0 : affcirc="A"
    endif
        varb=Tbalon+5
    if Tpano > varb and Cbalon > Tbalon then
        circBal=1    :affcirc="M"
    else circBal=0
        affcirc= "A"
    endif
    serout LCD,baud,(254,210,affcirc)
    return
    erreur:
    if def <> 0 then
        serout LCD,baud,(254,148,"ERR THERMOCOUPLE")
    else
        serout LCD,baud,(254,148,"ERR TEMPS MAX")
    endif
        serout LCD,baud,(254,212,"valider pour reset")
    do loop while valid=1 ;attente appui
    do loop while valid=0 ;attente relachement
    reset                        ;reset programme

MM

patrick63730 · Jun 19, 2025

Bonjour Michel je n'ai pas eu le temps de te lire mais les résultats de mes tests vont dans ce sens sur le montage en direct sur mon établi si je chauffe le TC baisse, j'inverse les fils du TC rouge et noir ça monte ,et parfois erreur également , sur le montage avec le câble de liaison entre pcb idem , je vais rentrer les nouveaux codes lorsque je rentre
Merci
Patrick

MGU · Jun 19, 2025

patrick63730 said:
Bonjour Michel je n'ai pas eu le temps de te lire mais les résultats de mes tests vont dans ce sens sur le montage en direct sur mon établi si je chauffe le TC baisse, j'inverse les fils du TC rouge et noir ça monte ,et parfois erreur également , sur le montage avec le câble de liaison entre pcb idem , je vais rentrer les nouveaux codes lorsque je rentre
Merci
Patrick

Nouvelle modif avec comptage des trames perdues qui sont ignorées:

Code:

;chauffage solaire douche piscine 19/06/25
;T panneau par thermocouple et liaison RS232
;Identifiant =123
#picaxe 20M2
setfreq M16
symbol LCD=B.0
symbol circBal=pinB.1
symbol Pbal=B.5
symbol valid=pinC.0
symbol DSbalon=C.5
symbol pano=C.7
symbol def =bit0
symbol Tpano =b1
symbol Tbalon =b2
symbol Cbalon =b3
symbol varb =b4
symbol memoTpano=b5
symbol delt =b6
symbol ident =b7
symbol cpt =b8
symbol affcirc=b9
symbol tp=b10
symbol baud =N2400_16
symbol baudT =T2400_16
dirsC=%0
dirsB=%00011111
pullup %1111111100000000
;****************************************
    pause 500
    serout LCD, baud,(254,1)    ;clean LCD
    serout LCD, baud,(254,131,"Tpa  Tba  Cba  P")
    serout LCD, baud,(254,192,"Tß") ;ß=alt+0223 => ° sur LCD
    serout LCD, baud,(254,212,"Trames perdues= 0")
    do
        memoTpano=Tpano   
        serin [20000,erreur],C.7,baudT,Tpano,def,ident ;reception Tpano,def,ident timeout 5s
    ;    Tpano=120 : def=0 : ident=122    ;pour simu
        if def<>0 then erreur
        if ident<>123 then    ;si iden non reconnu, on garde l'ancienne valeur
            inc tp
            serout LCD, baud,(254,228,#tp," ")
            Tpano=memoTpano
        endif       
        readtemp DSbalon,Tbalon ;sur C.5
        readadc Pbal, Cbalon
        serout LCD, baud,(254,195,#Tpano," ",254,200,#Tbalon," ", 254,205,#Cbalon," ")
        pause 200
        gosub gescirc
    loop
    ;*********************************************
    gescirc:
    if Tbalon>=90 or Tbalon>=Tpano then
        circBal=0 : affcirc="A"
    endif
        varb=Tbalon+5
    if Tpano > varb and Cbalon > Tbalon then
        circBal=1    :affcirc="M"
    else circBal=0
        affcirc= "A"
    endif
    serout LCD,baud,(254,210,affcirc)
    return
    erreur:
    if def <> 0 then
        serout LCD,baud,(254,148,"ERR THERMOCOUPLE")
    else
        serout LCD,baud,(254,148,"ERR TEMPS MAX")
    endif
        serout LCD,baud,(254,212,"valider pour reset")
    do loop while valid=1 ;attente appui
    do loop while valid=0 ;attente relachement
    reset                        ;reset programme

patrick63730 · Jun 19, 2025

je n'ai pas de retour T panneau affichage 0 et pas de consigne ballon 0

MGU · Jun 19, 2025

patrick63730 said:
je n'ai pas de retour T panneau affichage 0 et pas de consigne ballon 0

Tu as modifié les deux codes ?

patrick63730 · Jun 19, 2025

oui j'ai même refait a nouveau celui du 08M2

MGU · Jun 19, 2025

Pour essai, on va simuler une trame:
memoTpano=Tpano
serin [20000,erreur],C.7,baudT,Tpano,def,ident ;reception Tpano,def,ident timeout 5s
; Tpano=120 : def=0 : ident=123 ;pour simu
if def<>0 then erreur
Il faut mettre le ";" sur la ligne serin et supprimer celui de Tpano=.....
Résultat ?
MM

patrick63730 · Jun 19, 2025

j'ai un retour T panneau 120 c'est plausible mais il faut que je puisse mettre une consigne ballon sinon circu =0

MGU · Jun 19, 2025

patrick63730 said:
j'ai un retour T panneau 120 c'est plausible mais il faut que je puisse mettre une consigne ballon sinon circu =0

Oui, mais là, c'est une simulation, faut remettre comme avant.
Je vais remonter ma platine de tests pour faire un essai ici
A+
MM

patrick63730 · Jun 19, 2025

j'ai reçu mes pcb pour ma régul thermique sous sol mais il faut que je regarde ce que j'ai loupé je n'ai pas la sérigraphie ce n'est pas grave je connais le sujet j'y ai assez travaillé avec ton aide précieuse

MGU · Jun 19, 2025

patrick63730 said:
j'ai reçu mes pcb pour ma régul thermique sous sol mais il faut que je regarde ce que j'ai loupé je n'ai pas la sérigraphie ce n'est pas grave je connais le sujet j'y ai assez travaillé avec ton aide précieuse

Tu n'as pas sélectionné la couche "sérigraphie sup" (qui est pas erreur mentionnée inf), tu es resté sur assemblage.
assemblage c'est gris, sérigraphie c'est vert
MM

patrick63730 · Jun 19, 2025

Non non j'ai bien suis ton conseil c'était bien en Vert c'est à la commande que j'ai du oublier quelque chose mais je ferai mieux la prochaine fois
Patrick

MGU · Jun 19, 2025

patrick63730 said:
Non non j'ai bien suis ton conseil c'était bien en Vert c'est à la commande que j'ai du oublier quelque chose mais je ferai mieux la prochaine fois
Patrick

Bon,
Il y avait une salade de compteurs dans le code thermocouple

Code:

;MESURE TMAX31855 RS232 19/06/25
;lecture thermocouple par MAX31855 MM 13/06/25
;La broche SO va prendre successivement la valeur de chaque bit du registre.
; scanné poids fort en tête
;moyenne sur 4 mesures
;transmission : temp, def, identifiant=123
#picaxe 08M2
#no_data
symbol CLK=C.1        ; pulse horloge
symbol CSB=C.2        ;demande lecture  _____/
symbol SO=pinC.3      ;bit de donnée serial out
symbol def=bit0
symbol cpt=b1
symbol temp=b2
symbol cpt2=b3
symbol varw=w13         ;var temporaire
symbol cumul=w12
symbol temptherm=w11    ;tempé thermocouple
setfreq M4               
symbol baud=T2400_4
symbol baudN=N2400_4
;*****************************
#macro spin(varw)        ;macro SPIIN
    varw = 0
    for cpt = 1 to 16
      varw=varw * 2 + SO      ;décalage à gauche + SO (0 ou 1)   
      pulsout CLK,1           ;pulse horloge    
    next cpt   
#endmacro
;************************************
    pause 500   
    high CSB    ;première conversion
    Do  
        cumul=0
        for cpt2 = 1 to 4 
            pause 200     ;200 ms
            low CSB            ;lecture registre           
            spin(temptherm)    ;exécution macro 16 premiers bits (poid fort en tête   
            high CSB           ;nouvelle conversion   
            ;*****defaut **********************       
            def=temptherm//2        ;isol bit défaut       
            ;**** temp thermocouple ******************************         
            temptherm=temptherm/4        ;suppression des 2 derniers bits
            if temptherm>=$2000 then   ;test 1er bit des 14 bits pour valeur négative
              temptherm=0                    ;fixé à 0 si négatif   
            endif         
            temptherm=temptherm/4        ;suppression des décimales-> val entière
            temptherm=temptherm//256   ;valeur entière ; on garde les 8 derniers bits
            temp=temptherm    
            cumul=cumul + temp
        next cpt2
        temp=cumul/4       
        ;serout C.0, baudN,(254,148,#temp," ",#def," ",#123)        ;liaison RS232        
        serout C.0, baud,(temp,def,123)        ;liaison RS232         
      loop

Je vérifie aussi l'autre programme. J'ai vu que la consigne ballon n'était plus calibrée, va de 0 à 255
c'est ce que tu veux ?
MM

patrick63730 · Jun 19, 2025

Consigne ballon de 40 a 95 c'est suffisant

patrick63730 · Jun 19, 2025

je viens de m'apercevoir qu'a force de bricoler un des conducteurs du potar était coupé j'ai de nouveau un retour de consigne et un retour de T panneau j'ai sorti la DS du ballon pour faire baisser la T ballon et ça démarre avec 6 degrés de différence comme avant ça a l'air de fonctionner j'ai refait la liaison entre les pcb avec mo 3 x 0.5 souple je préfère au câble téléphone je surveillerai demain
super travail merci Michel bonne soirée
patrick

MGU · Jun 19, 2025

MàJ du code affichage:
Il n'y a plus d'alarme à la MST (enfin chez moi...à confirmer)
Je renonce à compter les trames perdues, si il y en a, ça complique pour rien, elle sera ignorée

Code:

;chauffage solaire douche piscine 19/06/25
;T panneau par thermocouple et liaison RS232
;Identifiant =123
#picaxe 20M2
setfreq M16
symbol LCD=B.0
symbol circBal=pinB.1
symbol Pbal=B.5
symbol RAZ=pinC.0
symbol DSbalon=C.5
symbol pano=C.7
symbol def =bit0
symbol Tpano =b1
symbol Tbalon =b2
symbol Cbalon =b3
symbol varb =b4
symbol memoTpano=b5
symbol delt =b6
symbol ident =b7
symbol cpt =b8
symbol affcirc=b9
symbol baud =N2400_16
symbol baudT =T2400_16
dirsC=%0
dirsB=%00011111
pullup %1111111100000000
;****************************************
    pause 500
    serout LCD, baud,(254,1)    ;clean LCD
    serout LCD, baud,(254,131,"Tpa  Tba  Cba  P")
    serout LCD, baud,(254,192,"Tß") ;ß=alt+0223 => ° sur LCD   
    def=0 : ident=123
    do
        memoTpano=Tpano          
        serin [20000,erreur],C.7,baudT,Tpano,def,ident ;reception Tpano,def,ident timeout 5s
        ;Tpano=120 : def=0 : ident=123 ;pour simu
        if def=1 and ident=123 then erreur
        if ident<>123 then   ;si iden non reconnu, on garde l'ancienne valeur
        Tpano=memoTpano
        endif       
        readtemp DSbalon,Tbalon ;sur C.5
        readadc Pbal, Cbalon
        Cbalon= 55 * Cbalon/250 +40
        serout LCD, baud,(254,195,#Tpano," ",254,200,#Tbalon," ", 254,205,#Cbalon," ")
        pause 200
        gosub gescirc
    loop
    ;*********************************************
    gescirc:
    if Tbalon>=90 or Tbalon>=Tpano then
        circBal=0 : affcirc="A"
    endif
        varb=Tbalon+5
    if Tpano > varb and Cbalon > Tbalon then
        circBal=1    :affcirc="M"
    else circBal=0
        affcirc= "A"
    endif
    serout LCD,baud,(254,210,affcirc)
    return
    erreur:
    if def <> 0 then
        serout LCD,baud,(254,148,"ERR THERMOCOUPLE")
    else
        serout LCD,baud,(254,148,"ERR TEMPS MAX")
    endif
        serout LCD,baud,(254,212,"appuyer sur RAZ")
    do loop while RAZ=1 ;attente appui
    do loop while RAZ=0 ;attente relachement
    reset                        ;reset programme

CBallon de 40 à 96 °C
Si l'affichage ne te plait pas,avec P = "M" ou "A" pour marche ou arrêt,..... change le
Les deux lignes du bas sont réservées aux message d'erreur et consigne de reset
Le poussoir s’appelle "RAZ" , il ne valide plus rien
MM

patrick63730 · Jun 19, 2025

oui a chaque MST il y avait le message erreur thermocouple ce qui aurait été le cas en cas de coupure ,mais j'ai une question comment font les picaxes pour conserver la mémoire sans alim ni batterie comme sur un pc ?
je suis en train de modifier le code pour la régulation solaire thermique je devrais y arriver
merci et bonne soirée
patrick

patrick63730 · Jun 20, 2025

bonjour Michel j'ai rentré le nouveau code , j'ai supprimé le + devant serin surement une faute de frappe PE6 n'en voulais pas ,après la prog j'ai eu l'erreur défaut thermocouple mais j'ai coupé l'alim et refait une MST disparition du défaut ça a l'air de fonctionner correctement je rends compte ce soir merci et bonne journée
patrick

MGU · Jun 20, 2025

patrick63730 said:
oui a chaque MST il y avait le message erreur thermocouple ce qui aurait été le cas en cas de coupure ,mais j'ai une question comment font les picaxes pour conserver la mémoire sans alim ni batterie comme sur un pc ?

Bonjour,
Il y a plusieurs type de mémoire dans les µC, volatile et non volatile. La non volatile est l'EEPROM, voir les commandes write et read associées.
Même type de mémoire que les clé USB.
Il y a deux phases pendant la programmation. une pour écrire le programme et la seconde pour effacer la mémoire EEPROM qui peut contenir des données.
Si on place une commande #no_data en début de programme, on indique que la mémoire EEPROM n'est pas utilisée et il n'y a pas de phase d'effacement de cette mémoire, on gagne quelques secondes...
Je ne sais pas d'où venait ce +, j'ai corrigé #180
MM

patrick63730 · Jun 20, 2025

bonsoir ça fonctionne bien pas de défaut heureusement que ce n'est plus une DS qui prend la T du panneau vu la température le ballon est a 90 et ça as du chauffer fort dans le panneau bravo beau travail
patrick

MGU · Jun 20, 2025

patrick63730 said:
bonsoir ça fonctionne bien pas de défaut heureusement que ce n'est plus une DS qui prend la T du panneau vu la température le ballon est a 90 et ça as du chauffer fort dans le panneau bravo beau travail

Si intéressé, on pourrait afficher et mémoriser en EEPROM les tempé Max et Mini du panneau, resetté par le poussoir
MM

patrick63730 said:
patrick

patrick63730 · Jun 21, 2025

Bonjour Michel oui c'est une bonne idée , je suis la température des appareils de froid avec des systèmes qui enregistrent , ça permet de savoir ce qui s'est passé
Patrick

MGU · Jun 21, 2025

patrick63730 said:
Bonjour Michel oui c'est une bonne idée , je suis la température des appareils de froid avec des systèmes qui enregistrent , ça permet de savoir ce qui s'est passé
Patrick

Bonjour,
Dans ce cas, voici un MàJ , Les deux lignes du bas affichent Tpamax et Tpamin, pour annules l'affichage, on appuie sur le poussoir RAZ, les deux tempé affichent la valeur instantannée.
J'ai pas encore fait la mémo sur EEPROM.
On peut aussi la même chose pour le ballon

Code:

;chauffage solaire douche piscine 21/06/25
;T panneau par thermocouple et liaison RS232
;Identifiant =123
;Affichage Tpamax et Tpamin
#picaxe 20M2
setfreq M16
symbol LCD=B.0
symbol circBal=pinB.1
symbol Pbal=B.5
symbol RAZ=pinC.0
symbol DSbalon=C.5
symbol pano=C.7
symbol def =bit0
symbol Tpano =b1
symbol Tbalon =b2
symbol Cbalon =b3
symbol varb =b4
symbol memoTpano=b5
symbol Tpamin=b6
symbol ident =b7
symbol cpt =b8
symbol affcirc=b9
symbol Tpamax=b10
symbol baud =N2400_16
symbol baudT =T2400_16
dirsC=%0
dirsB=%00011111
pullup %1111111100000000
;****************************************
    pause 500
    serout LCD, baud,(254,1)    ;clean LCD
    serout LCD, baud,(254,131,"Tpa  Tba  Cba  P")
    serout LCD, baud,(254,192,"Tß") ;ß=alt+0223 => ° sur LCD
    serout LCD, baud,(254,148,"Tpamax= ",254,212,"Tpamin= ")    
    def=0 : ident=123 :Tpamin=255
    do
        memoTpano=Tpano        
        serin [20000,erreur],C.7,baudT,Tpano,def,ident ;reception Tpano,def,ident timeout 5s
        ;Tpano=120 : def=0 : ident=123 ;pour simu
        if def=1 and ident=123 then erreur
        if ident<>123 then;si iden non reconnu, on garde l'ancienne valeur
        Tpano=memoTpano
        endif        
        readtemp DSbalon,Tbalon ;sur C.5
        readadc Pbal, Cbalon
        Cbalon= 55 * Cbalon/250 +40
        serout LCD, baud,(254,195,#Tpano," ",254,200,#Tbalon," ", 254,205,#Cbalon," ")
        pause 200
        if Tpano> Tpamax then
            Tpamax=Tpano
        endif    
        if Tpano<Tpamin then
            Tpamin=Tpano
        endif
        if RAZ=0 then
            do loop while RAZ=0
            Tpamax=Tpano
            Tpamin=Tpano
        endif
        serout LCD, baud,(254,156,#Tpamax," ",254,220,#Tpamin," ")    
        gosub gescirc
    loop
    ;*********************************************
    gescirc:
    if Tbalon>=90 or Tbalon>=Tpano then
        circBal=0 : affcirc="A"
    endif
        varb=Tbalon+5
    if Tpano > varb and Cbalon > Tbalon then
        circBal=1    :affcirc="M"
    else circBal=0
        affcirc= "A" 
    endif
    serout LCD,baud,(254,210,affcirc)
    return
    erreur:
    if def <> 0 then
        serout LCD,baud,(254,148,"ERR THERMOCOUPLE   ")
    else
        serout LCD,baud,(254,148,"ERR TEMPS MAX      ")
    endif
        serout LCD,baud,(254,212,"appuyer sur RAZ    ")
    do loop while RAZ=1 ;attente appui
    do loop while RAZ=0 ;attente relachement
    reset                        ;reset programme

MM

MGU · Jun 21, 2025

Un petit nouveau :

Code:

;chauffage solaire douche piscine 21/06/25
;T panneau par thermocouple et liaison RS232
;Identifiant =123
;Affichage Tpamax , Tpamin , idem Tbalon
#picaxe 20M2
setfreq M16
symbol LCD=B.0
symbol circBal=pinB.1
symbol Pbal=B.5
symbol RAZ=pinC.0
symbol DSbalon=C.5
symbol pano=C.7
symbol def =bit0
symbol Tpano =b1
symbol Tbalon =b2
symbol Cbalon =b3
symbol varb =b4
symbol memoTpano=b5
symbol Tpamin=b6
symbol ident =b7
symbol cpt =b8
symbol affcirc=b9
symbol Tpamax=b10
symbol Tbamax=b11
symbol Tbamin=b12
symbol baud =N2400_16
symbol baudT =T2400_16
dirsC=%0
dirsB=%00011111
pullup %1111111100000000
;****************************************

    pause 500
    serout LCD, baud,(254,1)    ;clean LCD
    serout LCD, baud,(254,132,"Tpa  Tba  Cba  P")
    serout LCD, baud,(254,192,"Tß") ;ß=alt+0223 => ° sur LCD
    serout LCD, baud,(254,148,"MAX ",254,212,"MIN ")  
    def=0 : ident=123 :Tpamin=255 : Tbamin=255
    do
        memoTpano=Tpano      
        serin [20000,erreur],C.7,baudT,Tpano,def,ident ;reception Tpano,def,ident timeout 5s
        ;Tpano=120 : def=0 : ident=123 ;pour simu
        if def=1 and ident=123 then erreur
        if ident<>123 then;si iden non reconnu, on garde l'ancienne valeur
        Tpano=memoTpano
        endif      
        readtemp DSbalon,Tbalon ;sur C.5
        readadc Pbal, Cbalon
        Cbalon= 55 * Cbalon/250 +40
        serout LCD, baud,(254,196,#Tpano," ",254,201,#Tbalon," ", 254,206,#Cbalon," ")
        pause 200
        if Tpano> Tpamax then
            Tpamax=Tpano
        endif  
        if Tpano<Tpamin then
            Tpamin=Tpano
        endif
        if Tbalon>Tbamax then
            Tbamax=Tbalon
        endif
        if Tbalon<Tbamin then
            Tbamin=Tbalon
        endif
        if RAZ=0 then
            do loop while RAZ=0
            Tpamax=Tpano
            Tpamin=Tpano
            Tbamax=Tbalon
            Tbamin=Tbalon
        endif
        serout LCD, baud,(254,152,#Tpamax," ",254,157,#Tbamax,254,216,#Tpamin," ",254,221,#Tbamin)  
        gosub gescirc
    loop
    ;*********************************************
    gescirc:
    if Tbalon>=90 or Tbalon>=Tpano then
        circBal=0 : affcirc="A"
    endif
        varb=Tbalon+5
    if Tpano > varb and Cbalon > Tbalon then
        circBal=1    :affcirc="M"
    else circBal=0
        affcirc= "A"
    endif
    serout LCD,baud,(254,211,affcirc)
    return
    erreur:
    if def <> 0 then
        serout LCD,baud,(254,148,"ERR THERMOCOUPLE   ")
    else
        serout LCD,baud,(254,148,"ERR TEMPS MAX      ")
    endif
        serout LCD,baud,(254,212,"appuyer sur RAZ    ")
    do loop while RAZ=1 ;attente appui
    do loop while RAZ=0 ;attente relachement
    reset                        ;reset programme

[/code]

patrick63730 · Jun 21, 2025

Je n'ai pas eu le temps de modifier mais c'est parfait, avec les picaxes on fait énormément de choses, j'ai travaillé dans l'industrie chez Michelin et je me rappelle des dépanneurs qui modifiaient les programmes en étant raccordés a la machine ,pas en USB il y as 40 ans c'était du port série et des pc énormes , certaines machines étaient branchées en permanence avec un écran et un clavier intégré , c'est ce que nous faisons aujourd'hui , j'ai fait un câble de programmation de 2M 50 le convertisseur et l'inverseur dans un boîtier et un câble de 80 cm en sortie avec les 4 fiches c'est plus facile pour travailler sur site et moins fragile
Merci pour ces modifs
Patrick

patrick63730 · Jun 21, 2025

Michel je viens de rentrer ton dernier code ,petit problème la T panneau est celle rentrée en simu si je la change c'est pareil ça donne comme T celle rentrée en simu
patrick

MGU · Jun 21, 2025

J'avais pas testé en réel, il y a un pb à l'initialisation de la Tpamin , qui vaut 0 à la mise sous tension. Il faudrait donc appuyer sur RAZ.
On peut aussi ajouter ce bout de code de 3 lignes qui a le même effet, c'est le : if Tpamin=0...endif

Code:

        serout LCD, baud,(254,196,#Tpano," ",254,201,#Tbalon," ", 254,206,#Cbalon," ")
        pause 200
        if Tpamin=0 then
            Tpamin=Tpano
        endif
        if Tpano> Tpamax then
            Tpamax=Tpano
        endif

J'avais aussi laissé en version simulation ( ; devant serin), c'est corrigé en #188

MM

patrick63730 · Jun 21, 2025

J'ai corrigé j'encode demain matin
Patrick

patrick63730 · Jun 22, 2025

Bonjour Michel picaxe programmée résultat ok
bonne journée a l'ombre patrick

MGU · Jun 22, 2025

patrick63730 said:
Bonjour Michel picaxe programmée résultat ok
bonne journée a l'ombre patrick

Bonjour,
Le LCD2004 en mieux employé maintenant. Ce qui n’empêche pas les alarmes, resettées par le même poussoir.
Bonne journée
MM

patrick63730 · Jun 22, 2025

Pour mes pcb qui sont arrivés sans sérigraphie j'ai vérifié sur ma commande le pcb est sérigraphié , je leur ai envoyé un mail pour savoir pourquoi il est arrivé sans la sérigraphie, je pense que c'est un oubli de leur part, je vais bien voir leur réponse
Patrick

MGU · Jun 22, 2025

patrick63730 said:
Pour mes pcb qui sont arrivés sans sérigraphie j'ai vérifié sur ma commande le pcb est sérigraphié , je leur ai envoyé un mail pour savoir pourquoi il est arrivé sans la sérigraphie, je pense que c'est un oubli de leur part, je vais bien voir leur réponse
Patrick

Je ne pense pas, tout est automatisé, la sérigraphie est incluse dans les gerber.
Si tu m’envoies le .dip du circuit, je peux jeter un oeil. (PJ dans un zip)
La sérigraphie doit apparaître dans la vision 3D de DiTrace et dans les vues de JLCPCB. Si on ne la voit: pas de sérigraphie
MM

patrick63730 · Jun 22, 2025

si si la sérigraphie sur la vue sur le site jlc elle est bien présente et mes pcb en sont dépourvus

MGU · Jun 22, 2025

Envoie une photo de tes PCB, et une vue de la commande, on verra la réponse....mais ça m'étonne.
MM

patrick63730 · Jun 23, 2025

Bonjour Michel j'ai reçu 2 réponses car j'ai fait une demande par leur site et une autre par mail une ou ils me demandent une photo et le no de commande (il est dans l'objet de mon mail). Je leur ai donc envoyé ,et une seconde ou ils me disent comment faire une réclamation mais je n'y comprends rien, sais tu comment je dois faire pour la réclamation, c'est du British pas bon pour moi

MGU · Jun 23, 2025

patrick63730 said:
Bonjour Michel j'ai reçu 2 réponses car j'ai fait une demande par leur site et une autre par mail une ou ils me demandent une photo et le no de commande (il est dans l'objet de mon mail). Je leur ai donc envoyé ,et une seconde ou ils me disent comment faire une réclamation mais je n'y comprends rien, sais tu comment je dois faire pour la réclamation, c'est du British pas bon pour moi

Bonjour,
La P.J. n'est pas lisible, trop petite et floue. Essaie autre chose..
MM

chauffage solaire douche piscine

Senior Member

Well-known member

Senior Member

Senior Member

Senior Member

Well-known member

Senior Member

Well-known member

Senior Member

Well-known member

Senior Member

Well-known member

Senior Member

Well-known member

Senior Member

Well-known member

Senior Member

Well-known member

Well-known member

Senior Member

Well-known member

Well-known member

Senior Member

Well-known member

Senior Member

Well-known member

Senior Member

Senior Member

Well-known member

Well-known member

Senior Member

Well-known member

Well-known member

Attachments

Senior Member

Well-known member

Senior Member

Well-known member

Attachments

Senior Member

Well-known member

Attachments

Senior Member