chrono agility !!!

;EMETTEUR BARRIERE
;Départ ou Arrivée par sélecteur
;Cellules IR sur Entrées C.0, C.1 ,C.2 
;MM 8/8/2014
;
	;les capteurs barrière sont sur C.0, C.1, C.2 sur interruption
	;La barrière est "depart" ou "arrivée" en ft de l'inverseur B.2. Départ si B.2=1 
	;Sur une barrière "Départ", le poussoir "alternate" envoie un code "Arrivée" et inversement.
	;Commutation Départ / Arrivée par inverseur. DepAriv: 1=Départ ;  0=Arrivée

	#picaxe 14M2
	dirsB= %111000
	symbol poussoir= pinC.4		;poussoir code alternatif
	symbol RAZ	=pinC.3			;poussoir code RAZ
	symbol DepAriv=pinB.2		;Inverseur barrière. Depariv =1 = barrière Départ
	symbol RF=B.5				;Emetteur Radio
	symbol flash=	B.3 		;témoin passage barrière
	pullup %0001111100000100	;Pullup sur B2, C.0, C;1, C.2, C.3, C.4	
	pwmout B.4, 25, 53			;PWM 38k
	setint OR %111,%111 		;interrupt sur Niveau haut de C.0 ou C.1 ou C.2 	
	
	Do 
		if RAZ=0 then
			high flash	; passage barrière
			pause 100
			rfout RF,("Z","Z","Z","Z","Z","Z","Z","Z")						
			pause 400
			low flash
		elseif poussoir=0 then
			high flash	; passage barrière
			pause 100
			If DepAriv=1 then				
				rfout RF,("A","A","A","A","A","A","A","A")	;si d?part=1, le poussoir envoie "Arriv?e"						
				else				
				rfout RF,("D","D","D","D","D","D","D","D")	;sinon, il envoie "D?part"
			endif
					
			pause 400
			low flash
		endif	
	loop		

interrupt:
	high flash
	pause 100
	if DepAriv=1 then		
		rfout RF,("D","D","D","D","D","D","D","D")	;si "depart"=1, l'interrupt envoie "depart"
	else
		rfout RF,("A","A","A","A","A","A","A","A")	;sinon, l'interrupt envoie "arriv?e"		
	endif
			
	pause 400
	low flash
	
	setint OR %111,%111	
	return

; CHRONO AU 1/100 EME DE SECONDE.
; COMMANDE PAR POUSSOIR OU PAR TOP RADIO 	
; MM 15/08/2014

; gestion Afficheur par CD4543	
;	 
#picaxe 28X2

setfreq M16
dirsB=%11111111		;broches B en sorties pour les codes chiffres
dirsA=%11111		;Pour les pulses LD sur les CD4543
;hsersetup B4800_16, %10 ; 4800 baud, inverted TXD pour afficheur led perso
hsersetup B2400_16, %10 ; 2400 baud, inverted TXD pour afficheur OLED 133Y 
symbol depart=pinC.1	;sur sortie Départ du 14M2 ou manuel.	pinC.1=0 si Appuyé
symbol Arrive=pinC.2	;Sur sortie Arrivée du 14M2 ou manuel	pinC.2=0 si Appuyé
symbol RAZ	=pinC.3		;Sur sortie RAZ du 14M2 ou manuel		pinC.3=0 si Appuyé
symbol LCD	=C.6		;sortie Hserout

symbol chiffr=b6
symbol digit=b7

symbol val=w13
	
	;calibfreq 0 	;à modifier pour calibration horloge: +X pour accélérer; -X pour ralenir
	settimer 64911	;reglage timer 1/100 s (voir doc) 

	pause 500		;pause initialisation LCD
	hserout LCD,(254,1)							;raz affichage LCD	
	hserout LCD,(254,128," CHRONO AGILITY ")	;affichage LCD
	
	Do		
		val=0
		do			;Attente top départ
			gosub affich 	;affiche 000,00
		loop while depart=1
			  	
		timer=0		;c'est parti, RAZ timer				;	
		do 			; Affichage du temps. Attente top arrivée
			val=timer
			gosub affich				
			if arrive=0 then exit	;attente arrivée
		loop
												
		do 			;Attente RAZ
			gosub affich				;affichage dernière valeur
		loop while RAZ=1 and depart=1 								
	loop
		
affich:	
	bintoascii val, b1,b2,b3,b4,b5				;décomposition asci i
	hserout LCD,(254,196,b1,b2,b3,",",b4,b5," s")	;affichage LCD
	
	digit=%01111		;sortie A.4 =0 ; donne 1 en sortie du ULN2803	
	chiffr=b5-48		;centièmes	
	gosub affchif		;affichage chiffre
	digit=%10111		;A.3=0	
	chiffr=b4-48		;dizièmes
	gosub affchif
	digit=%11011
	chiffr=b3-48		;unité secondes	
	gosub affchif
	digit=%11101		;dizaines sec
	chiffr=b2-48
	gosub affchif
	digit=%11110		;centaines sec
	chiffr=b1-48
	gosub affchif
	return
	
affchif:
	pinsB=chiffr		;chiffre en BCD sur port B
	pinsA=digit			;selection digit ;pulse LD sur port A 
	pinsA=%11111 		;toutes les sorties de l'ULN2803 à 0
	return