Pour aller (beaucoup) plus loin-T.bas

kfjl

Member
BONNE ANNEE!

Les modules LoRa Ra01 de AI ne sont pas faits pour être utilisés avec une "planche à pain".

View attachment 21788
L'intrus du post précédent.

N'importe quel module à base de SX1278 avec interface SPI fera l'affaire. J'ai pris le moins cher.

Code:
#PICAXE 20X2        'One-Page-LoRa-Transmit.bas 
#TERMINAL 9600 
#no_data 
#no_table 
 
'AI LoRa module Ra-01_V1.0  Semtech SX1278. NOT BREADBOARD FRIENDLY !!!!! 
'Power supply: 3.3V from computer USB or phone charger via FTDI module  
' 
'LoRa    Colour    Picaxe     
'''''''''''''''''''''' 
'RESET     Brown    B.6     
'3.3V    Red    +V        THREE point THREE VOLTS !!!.!!!     
'GND    Black    0V        GND 
'SCK    Yellow    B.7        hspi sck 
'MISO    Orange    B.5        hspi sdi 
'MOSI    Green    C.1        hspi sdo 
'NSS    White    B.3 
'DIO0    Grey    B.0        hint1 IRQ normally LOW (not used for transmitter) 
'ANT                    The antenna, if provided, or ~17cm wire 
' 
symbol NSS=B.3 
symbol SXReset=B.6 
symbol TXBase =$80                    'FIFO TX base address                                                           
output NSS 
output SXReset 
input B.0 
 
main: 
    hspisetup spimode00,spifast 
    let b0=0                                             'byte to send 
    gosub SXSetup 
     
loop1: 
    gosub Transmit 
    pause 1000 
goto loop1 
 
SXSetup:                                               
      
    low SXReset 
    pauseus 100     'Reset                     
    high SXReset   
     
    pause 10         'Allow a little time for SX1278 to reset, minimum 5mS 
 
    low NSS 
    hspiout($81,$00)    'Can only set LoRa mode from sleep mode 
    high NSS 
     
    low NSS 
    hspiout($81,$88)            'LoRa, low frequency mode 
    high NSS 
     
    low NSS 
    hspiout($89,$F3)                'PA_BOOST 
    high NSS 
     
    low NSS  
    HSPIOUT($91,$FF)                 'Set up for NO IRQ  
    high NSS 
     
    return 
     
Transmit: 'this transmists a 1 byte payload 
 
    low NSS 
    HSPIOUT($81,$09)     'Need to be in standby mode to setup packet 
    high NSS 
     
    low NSS 
    HSPIOUT($8D,TXBase)     'Set SPI ptr to FifoTXBaseAddr 
    high NSS      
                                                          
    low NSS 
    HSPIOUT($80)        'write the byte to Fifo 
    HSPIOUT(b0) 
    high NSS                         
     
    low NSS  
    HSPIOUT($81,$8B)     'Transmit, low frequency mode 
    high NSS  
 
    sertxd("Sent ",#b0,CR,LF)   'Doesn't test for TXDone! (see OPL_Transmitter.ino) 
 
    low NSS 
    HSPIOUT($81,$88)     'TX and RX to sleep, in LoRa mode (clear Fifo) 
    high NSS  
 
    if b0<10 then        'Count from 0 to 10 then start again 
        inc b0 
    else b0=0 
    endif 
     
return

LoRa en une page!

C'est encore un émétteur qui dit "sent" alors que ce n'est peut-être pas vrai.

Source: http://www.picaxeforum.co.uk/showthread.php?26481-LoRa-devices-for-long-range-wireless-applications&highlight=DRF1278+TX+RX+V1(1).BAS

A suivre...
 
Top